一聚教程网:一个值得你收藏的教程网站

热门教程

一款完美asp 验证邮箱 email代码

时间:2022-06-30 09:13:06 编辑:袖梨 来源:一聚教程网

dim webname,weburl,filepath,language,errortext
'检查email格式是否正确
function isvalidemail(email)
 dim names,name,i,c
 isvalidemail=true
 '使用@字符将email字符串分成几个子字符串并保存在names数组中
 names=split(email,"@")
 'ubound函数返回数组names的最大下标,ubound(names)<>1表明email字符串中存在的@字符
 '并不是一个,所以email不是有效的邮件地址格式
 if ubound(names)<>1 then
  isvalidemail=false
  exit function
 end if
 for each name in names   '数组names中的每一个元素
  if len(name)<=0 then   '字符串name内字符的数目
   isvalidemail=false
   exit function
  end if
  for i=1 to len(name)
   'mid(name,i,1)返回字符串name内第i个字符,lcase函数将该字符转换成小写形式
   c=lcase(mid(name,i,1))
   'instr 函数返回某字符串在另一字符串中第一次出现的位置。
   'instr("abcdefghijklmnopqrstuvwxyz_-.",c)<=0表明字符c不在字符串
   '"abcdefghijklmnopqrstuvwxyz_-."中,isnumeric(c)判断字符c是否为数字
   if instr("abcdefghijklmnopqrstuvwxyz_-.", c)<=0 and not isnumeric(c) then   '不支持中文格式地址
    isvalidemail=false
    exit function
   end if
   next
   'left(name,1)返回字符串name最左边一个字符。right(name,1)返回字符串name最右边一个字符
   if left(name,1)="." or right(name,1)="." then
    isvalidemail=false
    exit function
   end if
  next
  if instr(names(1),".")<=0 then   'email字符串中@右边部分不包含字符”.”
   isvalidemail=false
   exit function
  end if
  'instrrev函数返回某字符串在另一个字符串中出现的从结尾计起的的位置,
  'instrrev(names(1),".")得到字符"."在字符串names(1)中从结尾计起的位置
  i=len(names(1))- instrrev(names(1),".")
  '电子邮件最后一般为cn 或com,长度为2或3
  if i<>2 and i<>3 then
   isvalidemail=false
   exit function
  end if
  'email中存在字符串".."
  if instr(email,"..")>0 then
   isvalidemail=false
  end if
end function

热门栏目